Цифрові інтерфейси зв'язку: SPI

Інтерфейс I2C добре підходить для підключення великої кількості пристроїв лише двома лініями. Але невисока швидкість передачі, напівдуплексний режим роботи, залежність від підтягуючих резисторів і чутливість до перешкод роблять його не найкращим вибором для задач, де важлива продуктивність і стабільність. Особливо це помітно при роботі з дисплеями, пам’яттю або високочастотними сенсорами.

Саме тут на сцену виходить SPI — інтерфейс, який жертвує простотою підключення заради швидкості та надійності. Він дозволяє передавати дані значно швидше, підтримує повнодуплексний режим і забезпечує більш передбачувану роботу без складних механізмів арбітражу шини. SPI стає логічним вибором у системах, де важлива кожна мілісекунда і немає місця для компромісів.

SPI (від англ. Serial Peripheral Interface) - це високошвидкісний, синхронний, повнодуплексний, послідовний протокол зв'язку. Він розрахований на роботу на коротких дистанціях (в межах пристрою, як UART та I2C). Працює на швидкостях 1MHz - 200MHz, в залежності від частоти таймера мікроконтролера. SPI-зв’язок зазвичай використовується для взаємодії з такими пристроями, як пам’ять (SD-карти, EEPROM, Flash), дисплеї (OLED), датчики, а також АЦП/ЦАП.

На відміну від I2C, SPI не використовує адресацію для підтримки декількох ведених пристроїв. Натомість використовуються окремі лінії CS/SS — по одній для кожного пристрою.

Ведучий пристрій тримає всі лінії CS/SS у високому рівні (неактивними) і знижує рівень на потрібній лінії, щоб активувати відповідний ведений пристрій.

Режими SPI

SPI має 4 режими роботи, які визначаються двома параметрами:

• CPOL (Clock Polarity) — рівень тактового сигналу (SCK) у стані спокою.
• CPHA (Clock Phase) — на якому фронті сигналу зчитуються дані.

Комбінація цих параметрів утворює 4 режими:

Код ведучого пристрою:

#include <SPI.h>

const int SS1 = 10;
const int SS2 = 9;

void setup() {
  SPI.begin(); // запускаємо SPI як master

  // SS піни керують вибором slave
  pinMode(SS1, OUTPUT);
  pinMode(SS2, OUTPUT);

  // Вимикаємо всі slave (HIGH = неактивний)
  digitalWrite(SS1, HIGH);
  digitalWrite(SS2, HIGH);

  //Запускаємо Serial Monitor для виводу в консоль
  Serial.begin(9600);
}

void loop() {
  // Обмін зі slave 1
  digitalWrite(SS1, LOW);  // активуємо перший slave

  // SPI.transfer:
  // - відправляє байт
  // - одночасно читає байт у відповідь
  byte response = SPI.transfer(0xA1);

  digitalWrite(SS1, HIGH); // деактивуємо slave

  Serial.print("Відповідь від Slave1: ");
  Serial.println(response);

  delay(500);

  // Обмін зі slave 2
  digitalWrite(SS2, LOW);  // активуємо другий slave
  response = SPI.transfer(0xA1);
  digitalWrite(SS2, HIGH); // деактивуємо slave

  Serial.print("Відповідь від Slave2: ");
  Serial.println(response);

  delay(500);
}

Код веденого:

#include <SPI.h>

// Останні отримані дані від master
volatile byte received = 0;

// Дані, які slave буде повертати master
volatile byte toSend = 0x11;

void setup() {
  pinMode(MISO, OUTPUT); // лінія передачі даних назад master

  SPCR |= _BV(SPE);      // вмикаємо SPI у режимі slave
  SPI.attachInterrupt(); // дозволяємо обробку через переривання
}

// Викликається автоматично при кожному байті SPI
ISR(SPI_STC_vect) {
  received = SPDR; // читаємо що прийшло від master з регістру

  SPDR = toSend;   // готуємо відповідь для master
}

void loop() {
  // просто змінюємо дані, які віддаємо
  toSend++; // кожен цикл буде інше значення
}